woodfieldsのお気楽ツ～ル

■HSP3の「仕様」のようなもの

HSPをありがたく使わせていただいてます。
HSP3の「仕様」のようなものを思いつくままにまとめてみました。

●プログラムループと割り込み

#const WM_LBUTTONDOWN    $00000201    ; ウィンドウ通知メッセージ  マウス左ボタンを押し下げ
#const WM_RBUTTONDOWN    $00000204    ; ウィンドウ通知メッセージ  マウス右ボタンを押し下げ
screen 0,400,200
oncmd gosub *onWM_LBUTTONDOWN,WM_LBUTTONDOWN
oncmd gosub *onWM_RBUTTONDOWN,WM_RBUTTONDOWN
screen 0,400,200,0
color $ff,$ff,$ff : boxf
color 0,0,0 : pos 0, 0 : mes "マウス操作有効"
color 0,0,0 : pos 0,40 : mes "マウス左クリックまたは右クリックをしてください"
*mainloop
	wait 1	; <= ここで割り込みを受けつける場合も、受けつけないばあいも (割り込みを受けるとwait値は無視される)
	if val_WM_LBUTTONDOWN == 1 {
		val_WM_LBUTTONDOWN=0
		; ここでoncmd 0状態  割り込みでプログラムループを中断したくない
		color $ff,0,0 : boxf
		color 0,0,0 : pos 0, 0 : mes "マウス操作無効"
		color 0,0,0 : pos 0,40 : mes "[SPACE]キー入力でマウス操作を有効にできます"
	}
	if val_WM_RBUTTONDOWN == 1 {
		val_WM_RBUTTONDOWN=0
		; ここでoncmd 1状態  割り込みでプログラムループを中断してもよい
		color 0,0,$ff : boxf
		color 0,0,0 : pos 0, 0 : mes "マウス操作有効"
		color 0,0,0 : pos 0,40 : mes "マウス左クリックか[SPACE]キー入力をしてください"
	}
	getkey flg_key,32
	if flg_key == 1 {
		val_WM_LBUTTONDOWN=0
		val_WM_RBUTTONDOWN=0
		color $ff,$ff,$ff : boxf
		color 0,0,0 : pos 0, 0 : mes "マウス操作有効"
		color 0,0,0 : pos 0,40 : mes "マウス左クリックまたは右クリックをしてください"
		oncmd 1	; <= 割り込みを再開する
	}
	goto *mainloop
*onWM_LBUTTONDOWN
	val_WM_LBUTTONDOWN=1	; 割り込みサブルーチンの中では変数値の変更だけ
	title "マウス左クリックされました"
	oncmd 0	; <= 割り込みを一時停止する
	wait 25	; 割り込みを受けない
	title ""
	; 割り込みを一時停止したまま戻る
	return
*onWM_RBUTTONDOWN
	val_WM_RBUTTONDOWN=1	; 割り込みサブルーチンの中では変数値の変更だけ
	title "マウス右クリックされました"
	oncmd 0	; <= 割り込みを一時停止する
	wait 25	; 割り込みを受けない
	oncmd 1	; <= 割り込みを再開する
	title ""
	return

以下の例

#include "llmod3\\llmod3.hsp"
#include "llmod3\\img.hsp"
#include "llmod3\\listview.hsp"
#uselib  "user32.dll"
 #func SetFocus   "SetFocus"  sptr
 #func SendMessage  "SendMessageA"  int,int,int,int
		#const LVM_FIRST            $00001000
		#const LVM_ENSUREVISIBLE    (LVM_FIRST + 19)
		#const LVM_GETTOPINDEX      $00001027
 #cfunc	GetDoubleClickTime          "GetDoubleClickTime"
 #func	SetTimer                    "SetTimer"                  int, int, int, int
 #func	KillTimer                   "KillTimer"                 int, int
#define ctype RGB(%1,%2,%3) ((%1)|(%2<<8)|(%3<<16))
#const WM_NOTIFY            $0000004E
	#const NM_CLICK             -2
	#const NM_DBLCLK            -3
	#const NM_RCLICK            -5
	#const LVN_ITEMCHANGED      $FFFFFF9B
	#const NM_CUSTOMDRAW        $FFFFFFF4
		#const CDDS_PREPAINT        $00000001
		#const CDDS_ITEMPREPAINT    $00010001
		#const CDRF_NOTIFYITEMDRAW  $00000020
		#const CDRF_NEWFONT         $00000002
		#const CDRF_DODEFAULT       $00000000
	#const WM_MOUSEWHEEL        $0000020A
	#const WM_TIMER             $00000113
screen 0,800,500,0,3,3 : id_0=ginfo_sel : hwnd_0=hwnd
onkey gosub *lb_key
oncmd gosub *OnNotify, WM_NOTIFY
oncmd gosub *onTIMER, WM_TIMER
oncmd gosub *onMouseWheel,WM_MOUSEWHEEL
pos 0,0 : listview 200,200,$61000d-8 : hwnd_listview=objinfo(stat,2)
listaddcl 0,"No." ,300 ,0
repeat 50
	listadd cnt,"アイテム"+cnt,0
loop
index=-1
pos 0,200 : objsize 100,20
mes "以下のinputがフォーカス状態だと[↓][↑]入力は可能、マウスホイールは可能"
a="" : input a,100,20
mes "以下のmesbox/combox/listboxがフォーカス状態だと[↓][↑]入力は可能、マウスホイールは不可"
b="" : mesbox a,100,20
combox v_com,100,"APPLE\nORANGE\nGRAPE"
listbox v_list,100,"APPLE\nORANGE\nGRAPE"
mes "以下のbutton/chkboxがフォーカス状態だと[↓][↑]入力は不可(他のキーは可能)、マウスホイールは可能"
button gosub "button",*lb_bt
chkbox "chkbox",v_chk
*mainloop
	onkey 1
	wait 1
	onkey 0
	title "選択行INDEX : "+index+"  これまでのキー入力の回数:"+cnt_in_key+"  ｷｰｺｰﾄﾞ:"+code_key
	if flg_ITEMCHANGED_listview == 1 {
		flg_ITEMCHANGED_listview=0
		SetFocus hwnd
	}
	if flg_Lclck_listview {
		flg_Lclck_listview=0
		dialog "マウス左クリックしました"	; または SetFocus hwnd
	}
	if flg_Rclck_listview {
		flg_Rclck_listview=0
		dialog "マウス右クリックしました"	; または SetFocus hwnd
	}
	if flg_DLclck_listview {
		flg_DLclck_listview=0
		dialog "マウス左ダブルクリックしました"	; または SetFocus hwnd
	}
	goto *mainloop
*lb_bt
	return
*lb_key
	onkey 0
	if wparam == 27 {
		;[ESC]
		SetFocus hwnd	; フォーカスをウィンドウに移す
	}
	if wparam == 34 {
		;[PgDn]
		SetFocus hwnd
		gosub *scr_dw_listview
	}
	if wparam == 33 {
		;[PgUp]
		SetFocus hwnd
		gosub *scr_up_listview
	}
	if wparam == 40 {
		;[↓]
		SetFocus hwnd
		gosub *key_dw_listview
	}
	if wparam == 38 {
		;[↑]
		SetFocus hwnd
		gosub *key_up_listview
	}
	cnt_in_key++ : code_key=wparam
	return
*OnNotify
	onkey 0	; <= ここをコメントアウトすると問題は解決する
	dupptr nmhdr,lparam,12		; NMHDR structure
	if nmhdr(0) == hwnd_listview {
		if nmhdr(2) == NM_CUSTOMDRAW {
			; LISTVIEWカスタムドロー通知
			dupptr nmlcd,lparam,56	; NMLVCUSTOMDRAW structure
			if nmlcd(3) = CDDS_PREPAINT {
				return CDRF_NOTIFYITEMDRAW
			}
			if nmlcd(3) = CDDS_ITEMPREPAINT {
				if nmlcd(9) == index {	; アイテムNo.で判定し↓
					nmlcd(12)=RGB(0, $ff, 0)	; アイテムの文字色を変える
					nmlcd(13)=RGB($dd, $dd, $dd)	; アイテムの背景色を変える
				}
				return CDRF_NEWFONT
			}
		}
		if nmhdr(2) == LVN_ITEMCHANGED {
			; LISTVIEWアイテム変更通知
			flg_ITEMCHANGED_listview=1
			dupptr nmlcd,lparam,56	; ? structure
			index=nmlcd(3)
			return
		}
		if nmhdr(2) == NM_CLICK {
			SetTimer hwnd, 0, GetDoubleClickTime(), 0	; ダブルクリック時間のタイマー設定
			return
		}
		if nmhdr(2) == NM_DBLCLK {
			KillTimer hwnd, 0	; タイマー廃棄
			flg_DLclck_listview=1	; listview_0のダブルクリック
			return
		}
		if nmhdr(2) == NM_RCLICK {
			flg_Rclck_listview=1	; listviewの右クリック
			return
		}
	}
	return
*onTIMER
	if wparam == 0 {
		KillTimer hwnd, 0	; タイマー廃棄
		flg_Lclck_listview=1	; listviewの左クリック (選択行をクリックした場合のみ)
		return
	}
	return
*onMouseWheel
	val_MouseWheel=(wparam >> 16 & $FFFFFFFF)
	if (val_MouseWheel == -120) | (val_MouseWheel == 120) {
	}else{
		return 0
	}
	SetFocus hwnd
	flg_key_shift=0 : getkey flg_key_shift,16
	if flg_key_shift {
		if val_MouseWheel == -120 {
			;[PgDn]
			gosub *scr_dw_listview
		}
		if val_MouseWheel == 120 {
			;[PgUp]
			gosub *scr_up_listview
		}
	}else{
		if val_MouseWheel == -120 {
			;[↓]
			gosub *key_dw_listview
		}
		if val_MouseWheel == 120 {
			;[↑]
			gosub *key_up_listview
		}
	}
	return 0
*scr_dw_listview
	sel_listview id_listview : listget index_tmp,-1,0,2 : listhit : pre_index=stat : listmax max_listview, 0 : listmax max2_listview, 1 : SendMessage hwnd_listview,LVM_GETTOPINDEX,0,0 : top_line_listview=stat
	if index_tmp != index {
		if index_tmp != -1 {
			dialog "リストインデックスを修正取得しました\n*scr_dw_listview\n"+index+"\n"+index_tmp,1,this_apli_name
		}
		index=index_tmp
	}
	if max_listview > max2_listview {
		; リストビューが２画面以上なら
		; 1)インデックス更新
		if (top_line_listview <= index) & (index <= (top_line_listview+max2_listview-1)) {
			; リストビューの表示内なら
			if index == (top_line_listview+max2_listview-1) {
				; 表示内の末尾行なら
				index+=(max2_listview-1)	; 次の表示ページの末尾行へ
			}else{
				; 表示内の末尾行以外なら
				index=(top_line_listview+max2_listview-1)	; 現在の表示の末尾行へ
			}
		}else{
			; リストビューの表示外なら
			index=(top_line_listview+max2_listview-1)	; 現在の表示の末尾行へ
		}
		if index > (max_listview-1) {
			; リスト末尾行をオーバーしたら
			index=(max_listview-1)	; リスト末尾行へ
		}
		; 2)スクロール
		if (top_line_listview <= index) & (index <= (top_line_listview+max2_listview-1)) {
			; 現在の表示内なら
			sel_listview id_listview : listsel index	; フォーカス
		}else{
			; 現在の表示外なら
			SendMessage hwnd_listview,LVM_ENSUREVISIBLE,index,0	; 可視位置にスクロールバーを移動
			sel_listview id_listview : listsel index	; フォーカス
			sel_listview id_listview : listget index,-1,0,2 : listhit : pre_index=stat : listmax max_listview, 0 : listmax max2_listview, 1 : SendMessage hwnd_listview,LVM_GETTOPINDEX,0,0 : top_line_listview=stat
		}
	}else{
		; リストビューが１画面なら
		index=max_listview-1	; 現在の表示の末尾行へ
		sel_listview id_listview : listsel index	; フォーカス
	}
	return
*scr_up_listview
	sel_listview id_listview : listget index_tmp,-1,0,2 : listhit : pre_index=stat : listmax max_listview, 0 : listmax max2_listview, 1 : SendMessage hwnd_listview,LVM_GETTOPINDEX,0,0 : top_line_listview=stat
	if index_tmp != index {
		if index_tmp != -1 {
			dialog "リストインデックスを修正取得しました\n*scr_up_listview\n"+index+"\n"+index_tmp,1,this_apli_name
		}
		index=index_tmp
	}
	if max_listview > max2_listview {
		; リストビューが２画面以上なら
		; 1)インデックス更新
		if (top_line_listview <= index) & (index <= (top_line_listview+max2_listview-1)) {
			; リストビューの表示内なら
			if index == top_line_listview {
				; 表示内の先頭行なら
				index-=(max2_listview-1)	; 前の表示ページの先頭行へ
			}else{
				; 表示内の先頭行以外なら
				index=top_line_listview	; 現在の表示の先頭行へ
			}
		}else{
			; リストビューの表示外なら
			index=top_line_listview	; 現在の表示の先頭行へ
		}
		if index < 0 {
			; リスト先頭行をオーバーしたら
			index=0	; リスト先頭行へ
		}
		; 2)スクロール
		if (top_line_listview <= index) & (index <= (top_line_listview+max2_listview-1)) {
			; 現在の表示内なら
			sel_listview id_listview : listsel index	; フォーカス
		}else{
			; 現在の表示外なら
			SendMessage hwnd_listview,LVM_ENSUREVISIBLE,index,0	; 可視位置にスクロールバーを移動
			sel_listview id_listview : listsel index	; フォーカス
			sel_listview id_listview : listget index,-1,0,2 : listhit : pre_index=stat : listmax max_listview, 0 : listmax max2_listview, 1 : SendMessage hwnd_listview,LVM_GETTOPINDEX,0,0 : top_line_listview=stat
		}
	}else{
		; リストビューが１画面なら
		index=0	; 現在の表示の先頭行へ
		sel_listview id_listview : listsel index	; フォーカス
	}
	return
*key_dw_listview
	sel_listview id_listview : listget index_tmp,-1,0,2 : listhit : pre_index=stat : listmax max_listview, 0 : listmax max2_listview, 1 : SendMessage hwnd_listview,LVM_GETTOPINDEX,0,0 : top_line_listview=stat
	if index_tmp != index {
		if index_tmp != -1 {
			dialog "リストインデックスを修正取得しました\n*key_dw_listview\n"+index+"\n"+index_tmp,1,this_apli_name
		}
		index=index_tmp
	}
	; 1)インデックス更新
	if (top_line_listview <= index) & (index <= (top_line_listview+max2_listview-1)) {
		; リストビューの表示内なら
		index++	; １行後の行へ
	}else{
		; リストビューの表示外なら
		index=top_line_listview	; 現在の表示の先頭行へ
	}
	if index > (max_listview-1) {
		; リスト末尾行をオーバーしたら
		index=max_listview-1	; リスト末尾行へ
	}
	; 2)スクロール
	if (top_line_listview <= index) & (index <= (top_line_listview+max2_listview-1)) {
		; 現在の表示内なら
		sel_listview id_listview : listsel index	; フォーカス
	}else{
		; 現在の表示外なら
		SendMessage hwnd_listview,LVM_ENSUREVISIBLE,index,0	; 可視位置にスクロールバーを移動
		sel_listview id_listview : listsel index	; フォーカス
		sel_listview id_listview : listget index,-1,0,2 : listhit : pre_index=stat : listmax max_listview, 0 : listmax max2_listview, 1 : SendMessage hwnd_listview,LVM_GETTOPINDEX,0,0 : top_line_listview=stat
	}
	return
*key_up_listview
	sel_listview id_listview : listget index_tmp,-1,0,2 : listhit : pre_index=stat : listmax max_listview, 0 : listmax max2_listview, 1 : SendMessage hwnd_listview,LVM_GETTOPINDEX,0,0 : top_line_listview=stat
	if index_tmp != index {
		if index_tmp != -1 {
			dialog "リストインデックスを修正取得しました\n*key_up_listview\n"+index+"\n"+index_tmp,1,this_apli_name
		}
		index=index_tmp
	}
	; 1)インデックス更新
	if (top_line_listview <= index) & (index <= (top_line_listview+max2_listview-1)) {
		; リストビューの表示内なら
		index--	; １行前の行へ
	}else{
		; リストビューの表示外なら
		index=top_line_listview+max2_listview-1	; 現在の表示の末尾行へ
	}
	if index < 0 {
		; リスト先頭行をオーバーしたら
		index=0	; リスト先頭行へ
	}
	; 2)スクロール
	if (top_line_listview <= index) & (index <= (top_line_listview+max2_listview-1)) {
		; 現在の表示内なら
		sel_listview id_listview : listsel index	; フォーカス
	}else{
		; 現在の表示外なら
		SendMessage hwnd_listview,LVM_ENSUREVISIBLE,index,0	; 可視位置にスクロールバーを移動
		sel_listview id_listview : listsel index	; フォーカス
		sel_listview id_listview : listget index,-1,0,2 : listhit : pre_index=stat : listmax max_listview, 0 : listmax max2_listview, 1 : SendMessage hwnd_listview,LVM_GETTOPINDEX,0,0 : top_line_listview=stat
	}
	return

  プログラムの流れ                      [ﾒｲﾝﾌﾟﾛｸﾞﾗﾑ]
                                       +------------+
  *1 このwaitで割込が発生する。        |ﾌﾟﾗｸﾞｲﾝ     |
  *2 割込処理中は割込禁止とする。      |ﾓｼﾞｭｰﾙ      |
     ただしWM_NOTIFYﾒｯｾｰｼﾞの取得では   |ﾏｸﾛ定義     |
     onkey 0の割込制御は使えない。     +------------+
  *3 *1のwaitの直後で割込禁止とする。  |設定その他  | onexit/onkey/onclick命令で
     ﾌﾟﾛｸﾞﾗﾑﾙｰﾌﾟおよびｻﾌﾞﾙｰﾁﾝで新たな  |            | 割り込みを定義する
     割込が発生しないように。          +------------+
  *4 *1のwaitの直前で割込許可とする。  |画面作成    | oncmd命令やbutton命令で
                                       |            | 割り込みを定義する
  (注意)                               +------------+
  WM_NOTIFYﾒｯｾｰｼﾞの取得ではは、*2と*3  |ﾌﾟﾛｸﾞﾗﾑﾙｰﾌﾟ |
  のoncmdの割込制御は使えない。        |*pl         |<--+
  *4のoncmdの割込制御も無意味になる。  | onkey 1  *4|   |
                      (各種操作)       | onclick 1  |   |
   [割込ﾌﾟﾛｸﾞﾗﾑ]     割り込み発生      |(oncmd 1)   |   |
   +------------+<---------------------+ wait 1   *1|   |
   |(onkey 0) *2+--waitの次行に戻る--->| onkey 0  *3|   |
   | onclick 0  |                      | onclick 0  |   |
   |(oncmd 0)   |                      |(oncmd 0)   |   |
   |            |     +----------+     |            |   |
   | 割込A      +---->|ｻﾌﾞﾙｰﾁﾝ   |     |            |   |
   |   FlgAｾｯﾄ  |<----+実際の処理|     | (FlgA判定) |   |
   |            |     +----------+     |    goto *pl+---+ 描画更新が必要なときは
   |            |                      |            |   | 必ずﾌﾟﾛｸﾞﾗﾑﾙｰﾌﾟに戻ること
   | 割込B      |     +----------+     |            |   |
   |   FlgBｾｯﾄ  |     |ｻﾌﾞﾙｰﾁﾝ   |<----+ (FlgB判定) |   |
   |            |     |実際の処理+---->| -> goto *pl+---+
   |            |     +----------+     |            |   |
   +------------+                      |            |   |
                                       |            |   |
                      +----------+     |            |   |
                      |ｻﾌﾞﾙｰﾁﾝ   |<----+割込外の条件|   |
                      |実際の処理+---->| -> goto *pl+---+
                      +----------+     |            |   |
                                       |            |   |
                                       |    goto *pl+---+
                                       +------------+

■割り込みプログラム例

●ウィンドウ

■ｱｸﾃｨﾌﾞｳｨﾝﾄﾞｳと操作対象ｳｨﾝﾄﾞｳ

■ダブルクリック

#include "user32.as"	; SetClassLong、GetDoubleClickTime、SetTimer、KillTimerを使用
	#const GCL_STYLE           -26	; ウィンドウクラスのスタイルを書き換えます
		#const  CS_DBLCLKS     $00000008	; ダブルクリックを受けつける
; ウィンドウ通知メッセージ
#const WM_LBUTTONDBLCLK        $00000203	; マウス左ボタンをダブルクリック
#const WM_LBUTTONDOWN          $00000201	; マウス左ボタンを押し下げ
;#const WM_LBUTTONUP            $00000202	; マウス左ボタンを離した
;#const WM_MBUTTONDBLCLK        $00000209	; マウス中央ボタンをダブルクリック
;#const WM_MBUTTONDOWN          $00000207	; マウス中央ボタンを押し下げ
;#const WM_MBUTTONUP            $00000208	; マウス中央ボタンを離した
;#const WM_RBUTTONDBLCLK        $00000204	; マウス右ボタンをダブルクリック
;#const WM_RBUTTONDOWN          $00000205	; マウス右ボタンを押し下げ
;#const WM_RBUTTONUP            $00000206	; マウス右ボタンを離した
#const WM_TIMER                $00000113	; タイマーのタイムアウトを通知
screen 0
SetClassLong hwnd, -26, CS_DBLCLKS
oncmd gosub *OnMOUSEDLeft, WM_LBUTTONDBLCLK
oncmd gosub *OnMOUSELeft, WM_LBUTTONDOWN
oncmd gosub *OnTIMOUT, WM_TIMER
stop
*OnMOUSELeft
	GetDoubleClickTime
	SetTimer hwnd, 0, stat, 0	; ダブルクリック時間のタイマー設定
	return
*OnMOUSEDLeft
	KillTimer hwnd, 0	; タイマー廃棄
	dialog "ダブルクリックされました"
	return
*OnTIMOUT
	KillTimer hwnd, 0	; タイマー廃棄
	dialog "シングルクリックされました"
	return

■dialog

■子画面化

;===============================================================
; 最前面ウィンドウをチェック
;===============================================================
#module _chk_topwin
	;---------------------------------------------------------------
	#uselib  "user32.dll"
	 #cfunc GetForegroundWindow        "GetForegroundWindow"
	 #func GetWindow                   "GetWindow"                  sptr,sptr
		;                                                           HWND hWnd,            ウィンドウのハンドル
		;                                                           UINT uCmd             関係
		#const GW_CHILD              $00000005						; 指定したウィンドウが親ウィンドウの場合は、Z オーダーが一番上の子ウィンドウのハンドルを取得します。それ以外の場合は、NULL が返ります。この関数は、指定されたウィンドウの子ウィンドウだけを調べます。それより下位の子孫は調べません。 
		#const GW_ENABLEDPOPUP       $00000006						; Windows 2000：指定したウィンドウをオーナーとする有効なポップアップウィンドウのハンドルを取得します（ この検索では、GW_HWNDNEXT で見つかる最初のウィンドウを使います）。有効なポップアップウィンドウがない場合は、指定したウィンドウのハンドルが返ります。 
		#const GW_HWNDFIRST          $00000000						; 指定したウィンドウと同じ種類で最も高い Z オーダーを持つウィンドウのハンドルを取得します。指定したウィンドウが最前面ウィンドウの場合は、最も高い Z オーダーを持つ最前面ウィンドウのハンドルが返ります。指定したウィンドウがトップレベルウィンドウの場合は、最も高い Z オーダーを持つトップレベルウィンドウのハンドルが返ります。指定したウィンドウが子ウィンドウの場合は、最も高い Z オーダーを持つ兄弟ウィンドウのハンドルが返ります。 
		#const GW_HWNDLAST           $00000001						; 指定したウィンドウと同じ種類で最も低い Z オーダーを持つウィンドウのハンドルを取得します。指定したウィンドウが最前面ウィンドウの場合は、最も低い Z オーダーを持つ最前面ウィンドウのハンドルが返ります。指定したウィンドウがトップレベルウィンドウの場合は、最も低い Z オーダーを持つトップレベルウィンドウのハンドルが返ります。指定したウィンドウが子ウィンドウの場合は、最も低い Z オーダーを持つ兄弟ウィンドウのハンドルが返ります。 
		#const GW_HWNDNEXT           $00000002						; 指定したウィンドウより Z オーダーが 1 つ下のウィンドウのハンドルを取得します。指定したウィンドウが最前面ウィンドウの場合は、1 つ下の最前面ウィンドウのハンドルが返ります。指定したウィンドウがトップレベルウィンドウの場合は、1 つ下のトップレベルウィンドウのハンドルが返ります。指定したウィンドウが子ウィンドウの場合は、1 つ下の兄弟ウィンドウのハンドルが返ります。 
		#const GW_HWNDPREV           $00000003						; 指定したウィンドウより Z オーダーが 1 つ上のウィンドウのハンドルを取得します。指定したウィンドウが最前面ウィンドウの場合は、1 つ上の最前面ウィンドウのハンドルが返ります。指定したウィンドウがトップレベルウィンドウの場合は、1 つ上のトップレベルウィンドウのハンドルが返ります。指定したウィンドウが子ウィンドウの場合は、1 つ上の兄弟ウィンドウのハンドルが返ります。 
		#const GW_OWNER              $00000004						; 指定したウィンドウのオーナーウィンドウのハンドルを取得します。詳細については、「」を参照してください。 
	 #cfunc IsWindowVisible            "IsWindowVisible"            sptr		; WS_VISIBLE スタイルを持つ場合は、0 以外の値が返ります。
		;                                                           HWND hWnd  調査するウィンドウのハンドルを指定します。
	;---------------------------------------------------------------
	; 指定した複数のウィンドウのどれが最前面か調べる
	;   フォーカスを失っているウィンドウでも最善面かどうか判定できる
	;   自分よりZOrder上のウィンドウを総当りして、指定したウィンドウがZOrder上に存在しないかないか調べている
	;---------------------------------------------------------------
	#defcfunc chk_topwin_sel array v	; 新関数「chk_topwin_sel」を生成
	; array v : 前面かどうか調べるウィンドウを先頭にして兄弟ウィンドウをセット
	; 戻り値  : 1 最前面
	hwmd_tmp=v(0)
	ret=0
	if hwmd_tmp == GetForegroundWindow() {
		; 最前面ウィンドウである
		ret=1
	}else{
		if IsWindowVisible(hwmd_tmp) {
			; 表示されているがフォーカスを失っているばあい
			ret=1
			dim list_hws,8 : list_hws=v(1),v(2),v(3),v(4),v(5),v(6),v(7)
			repeat
				GetWindow hwmd_tmp,GW_HWNDPREV		; ZOrderがひとつ上のウィンドウを調べる
				hwnd_prev=stat
				if hwnd_prev {
					if IsWindowVisible(hwnd_prev) {
						; 手前に可視のウィンドウが存在する
						repeat 8,0
							hwnd_cnt=list_hws(cnt)
							if hwnd_cnt == 0 : break
							if hwnd_prev == hwnd_cnt {
								; 手前の可視のウィンドウは引数リストの２番目以降のいずれかのウィンドウである
								ret=0
								break
							}
						loop
						; 手前のウィンドウは可視ウィンドウであっても引数リストの２番目以降のいずれかのウィンドウではない
					}
					hwmd_tmp=hwnd_prev		; ZOrderがもうひとつ上のウィンドウを調べる
				}else{
					; ZOrderがひとつ上のウィンドウがもう存在しなければ最前面と判断する
					break
				}
			loop
		}
	}
	return ret
#global
;===============================================================
; Zオーダーを少しだけ
;===============================================================
#module _zorder
	#uselib  "user32.dll"
	 #func GetWindow                  "GetWindow"                   sptr,sptr
		;                                                           HWND hWnd,            元ウィンドウのハンドル
		;                                                           UINT uCmd             関係
		#const GW_CHILD              $00000005						; 指定したウィンドウが親ウィンドウの場合は、Z オーダーが一番上の子ウィンドウのハンドルを取得します。それ以外の場合は、NULL が返ります。この関数は、指定されたウィンドウの子ウィンドウだけを調べます。それより下位の子孫は調べません。 
		#const GW_ENABLEDPOPUP       $00000006						; Windows 2000：指定したウィンドウをオーナーとする有効なポップアップウィンドウのハンドルを取得します（ この検索では、GW_HWNDNEXT で見つかる最初のウィンドウを使います）。有効なポップアップウィンドウがない場合は、指定したウィンドウのハンドルが返ります。 
		#const GW_HWNDFIRST          $00000000						; 指定したウィンドウと同じ種類で最も高い Z オーダーを持つウィンドウのハンドルを取得します。指定したウィンドウが最前面ウィンドウの場合は、最も高い Z オーダーを持つ最前面ウィンドウのハンドルが返ります。指定したウィンドウがトップレベルウィンドウの場合は、最も高い Z オーダーを持つトップレベルウィンドウのハンドルが返ります。指定したウィンドウが子ウィンドウの場合は、最も高い Z オーダーを持つ兄弟ウィンドウのハンドルが返ります。 
		#const GW_HWNDLAST           $00000001						; 指定したウィンドウと同じ種類で最も低い Z オーダーを持つウィンドウのハンドルを取得します。指定したウィンドウが最前面ウィンドウの場合は、最も低い Z オーダーを持つ最前面ウィンドウのハンドルが返ります。指定したウィンドウがトップレベルウィンドウの場合は、最も低い Z オーダーを持つトップレベルウィンドウのハンドルが返ります。指定したウィンドウが子ウィンドウの場合は、最も低い Z オーダーを持つ兄弟ウィンドウのハンドルが返ります。 
		#const GW_HWNDNEXT           $00000002						; 指定したウィンドウより Z オーダーが 1 つ下のウィンドウのハンドルを取得します。指定したウィンドウが最前面ウィンドウの場合は、1 つ下の最前面ウィンドウのハンドルが返ります。指定したウィンドウがトップレベルウィンドウの場合は、1 つ下のトップレベルウィンドウのハンドルが返ります。指定したウィンドウが子ウィンドウの場合は、1 つ下の兄弟ウィンドウのハンドルが返ります。 
		#const GW_HWNDPREV           $00000003						; 指定したウィンドウより Z オーダーが 1 つ上のウィンドウのハンドルを取得します。指定したウィンドウが最前面ウィンドウの場合は、1 つ上の最前面ウィンドウのハンドルが返ります。指定したウィンドウがトップレベルウィンドウの場合は、1 つ上のトップレベルウィンドウのハンドルが返ります。指定したウィンドウが子ウィンドウの場合は、1 つ上の兄弟ウィンドウのハンドルが返ります。 
		#const GW_OWNER              $00000004						; 指定したウィンドウのオーナーウィンドウのハンドルを取得します。詳細については、「」を参照してください。 
	;---------------------------------------------------------------
	#defcfunc get_zorder int h	; 新関数「get_zorder」を生成
	GetWindow h,GW_HWNDPREV : h_p=stat
	GetWindow h,GW_HWNDNEXT : h_n=stat
	ret=""+h_p+">"+h+">"+h_n
	return ret
	;---------------------------------------------------------------
#global
;===============================================================
#uselib  "user32.dll"
 #func SetParent            "SetParent"           sptr,sptr
	;                                             HWND hWndChild,     ウィンドウのハンドル
	;                                             HWND hWndNewParent  新しい親ウィンドウ
 #cfunc GetForegroundWindow "GetForegroundWindow"
 #func GetWindow            "GetWindow"           sptr,sptr
	;                                             HWND hWnd,           元ウィンドウのハンドル
	;                                             UINT uCmd            関係
	#const GW_HWNDNEXT      $00000002             ; 指定したウィンドウより Z オーダーが 1 つ下のウィンドウのハンドルを取得
	#const GW_HWNDPREV      $00000003             ; 指定したウィンドウより Z オーダーが 1 つ上のウィンドウのハンドルを取。
 #cfunc IsWindowVisible     "IsWindowVisible"     sptr               ; WS_VISIBLE スタイルを持つ場合は、0 以外の値が返ります。
	;                                             HWND hWnd   調査するウィンドウのハンドルを指定します。
#const WM_LBUTTONDOWN       $00000201             ; マウス左ボタンを押し下げ通知メッセージ
onkey gosub *onKeyOn
screen 0,800,500,0 : hwnd_0=hwnd
objsize 200,20 : button gosub "全子ウィンドウ表示",*view_all
color $ff,0,0
pos 210, 10 : mes "マウスクリックで任意のウインドウを前面にしてください。"
pos  40, 30 : mes "スペースキー入力で gsel <ScreenID>,-1 が実行されて非表示になります。"
pos  40, 60 : mes "閉じて非表示になったウィンドウが"
pos  40, 80 : mes "下にまわり込むのがわかります。"
pos  40,110 : mes "いろいろやってみてください。"
color
screen 2,400,200,0,350, 50 : hwnd_2=hwnd : title "screen2("+hwnd_2+")"
oncmd gosub *OnMOUSELeft, WM_LBUTTONDOWN
SetParent hwnd_2,hwnd_0
screen 3,400,200,0,200,150 : hwnd_3=hwnd : title "screen3("+hwnd_3+")"
oncmd gosub *OnMOUSELeft, WM_LBUTTONDOWN
SetParent hwnd_3,hwnd_0
screen 4,400,200,0, 50,250 : hwnd_4=hwnd : title "screen4("+hwnd_4+")"
oncmd gosub *OnMOUSELeft, WM_LBUTTONDOWN
SetParent hwnd_4,hwnd_0
gsel 0 : title "screen0("+hwnd_0+")  screen2("+hwnd_2+")  screen3("+hwnd_3+")  screen4("+hwnd_4+")"
stop
*view_all
	gsel 2,1 : color $ff,$ff,$ff : boxf : color
	gsel 3,1 : color $ff,$ff,$ff : boxf : color
	gsel 4,1 : color $ff,$ff,$ff : boxf : color
	count_space_on=0
	return
*OnMOUSELeft
	if (ginfo_intid == 2) | (ginfo_intid == 3) | (ginfo_intid == 4) {
	gosub *view_ZOrder
	return
*view_ZOrder
	if IsWindowVisible(hwnd_2) {
		gsel 2
		color $ff,$ff,$ff : boxf : color
		pos 0,0 : mes "(上)>このｳｨﾝﾄﾞｳ>(下)  "+get_zorder(hwnd_2)+"\n[注意]ｳｨﾝﾄﾞｳは不可視(非表示)かも"
	}
	if IsWindowVisible(hwnd_3) {
		gsel 3
		color $ff,$ff,$ff : boxf : color
		pos 0,0 : mes "(上)>このｳｨﾝﾄﾞｳ>(下)  "+get_zorder(hwnd_3)+"\n[注意]ｳｨﾝﾄﾞｳは不可視(非表示)かも"
	}
	if IsWindowVisible(hwnd_4) {
		gsel 4
		color $ff,$ff,$ff : boxf : color
		pos 0,0 : mes "(上)>このｳｨﾝﾄﾞｳ>(下)  "+get_zorder(hwnd_4)+"\n[注意]ｳｨﾝﾄﾞｳは不可視(非表示)かも"
	}
	return
*onKeyOn
	;[space]
	if wparam == 32 {
		gosub *close_sub
	}
	return
*close_sub
	hwnd_bfr=GetForegroundWindow()		; 最前面ウィンドウ
	if (hwnd_bfr == 0) | (hwnd_bfr == hwnd_0) {
		hwnd_bfr=0
		if IsWindowVisible(hwnd_2) {
			dim list_hws,8 : list_hws=hwnd_2,hwnd_3,hwnd_4	; 前面かどうか調べるウィンドウを先頭にして兄弟ウィンドウをセット
			if chk_topwin_sel(list_hws) == 1 {
				hwnd_bfr=hwnd_2
			}
		}
		if IsWindowVisible(hwnd_3) {
			dim list_hws,8 : list_hws=hwnd_3,hwnd_2,hwnd_4	; 前面かどうか調べるウィンドウを先頭にして兄弟ウィンドウをセット
			if chk_topwin_sel(list_hws) == 1 {
				hwnd_bfr=hwnd_3
			}
		}
		if IsWindowVisible(hwnd_4) {
			dim list_hws,8 : list_hws=hwnd_4,hwnd_2,hwnd_3	; 前面かどうか調べるウィンドウを先頭にして兄弟ウィンドウをセット
			if chk_topwin_sel(list_hws) == 1 {
				hwnd_bfr=hwnd_4
			}
		}
	}
	if hwnd_bfr == 0 : return
	if hwnd_bfr == hwnd_2 : id_bfr=2
	if hwnd_bfr == hwnd_3 : id_bfr=3
	if hwnd_bfr == hwnd_4 : id_bfr=4
	gsel id_bfr,-1
	gosub *view_ZOrder
	return

●オブジェクト

■オブジェクトID

■mesbox

■listview

; listviewが配置されているウィンドウをウィンドウスタイルGWL_STYLEのWS_DISABLEDで操作禁止にする
; listadd、listselは有効、EnableWindowで操作禁止にするのと同じ結果
#include "llmod3\\llmod3.hsp"
#include "llmod3\\img.hsp"
#include "llmod3\\listview.hsp"
;↑llmod3 配布モジュールファイル使用
	#uselib  "user32.dll"
	 #func GetWindowLong         "GetWindowLongA"  sptr,sptr
		;                                          HWND hWnd,       ウィンドウのハンドル
		;                                          int nIndex       取得する値のオフセット
	 #func SetWindowLong         "SetWindowLongA"  sptr,sptr,sptr
		;                                          HWND hWnd,       ウィンドウのハンドル
		;                                          int nIndex,      設定する値のオフセット
		;                                          LONG dwNewLong   新しい値
		#const GWL_STYLE         $FFFFFFF0         ; -16 ウィンドウスタイル
			#const WS_DISABLED   0x08000000        ; 無効 (使用不能) なウィンドウを作成します。無効なウィンドウは、有効にするまで、ユーザーからの入力を受け取りません。
	screen 0 : hwnd_0=hwnd
	pos 5,0 : listview 600,400,$210000+1+8+4 : h_list=objinfo(id_list,2)
	listaddcl 0,"No.",600,300
	repeat 10
		listadd cnt,""+cnt,0,0
	loop
listsel 3
title "操作許可中"
wait 200
GetWindowLong hwnd_0, GWL_STYLE : SetWindowLong hwnd_0, GWL_STYLE, stat | WS_DISABLED
title "操作禁止中"
wait 100
listadd 5,"5番目",0,0
wait 100
listsel 5
wait 200
GetWindowLong hwnd_0, GWL_STYLE : SetWindowLong hwnd_0, GWL_STYLE, stat | WS_DISABLED ^ WS_DISABLED
title "操作許可中"
stop

; listviewをウィンドウスタイルGWL_STYLEのWS_DISABLEDで操作禁止にする
; listadd、listselは有効で、操作禁止中も罫線が消えない
#include "llmod3\\llmod3.hsp"
#include "llmod3\\img.hsp"
#include "llmod3\\listview.hsp"
;↑llmod3 配布モジュールファイル使用
	#uselib  "user32.dll"
	 #func GetWindowLong        "GetWindowLongA"  sptr,sptr
		;                                         HWND hWnd,            ウィンドウのハンドル
		;                                         int nIndex            取得する値のオフセット
	 #func SetWindowLong        "SetWindowLongA"  sptr,sptr,sptr
		;                                         HWND hWnd,            ウィンドウのハンドル
		;                                         int nIndex,           設定する値のオフセット
		;                                         LONG dwNewLong        新しい値
		#const GWL_STYLE        $FFFFFFF0         ; -16 ウィンドウスタイル
			#const WS_DISABLED  $08000000         ; 無効 (使用不能) なウィンドウを作成します。無効なウィンドウは、有効にするまで、ユーザーからの入力を受け取りません。
	screen 0 : hwnd_0=hwnd
	pos 5,0 : listview 600,400,$210000+1+8+4 : h_list=objinfo(id_list,2)
	listaddcl 0,"No.",600,300
	repeat 10
		listadd cnt,""+cnt,0,0
	loop
listsel 3
title "操作許可中"
wait 200
GetWindowLong h_list, GWL_STYLE : SetWindowLong h_list, GWL_STYLE, stat | WS_DISABLED
title "操作禁止中"
wait 100
listadd 5,"5番目",0,0
wait 100
listsel 5
wait 200
GetWindowLong h_list, GWL_STYLE : SetWindowLong h_list, GWL_STYLE, stat | WS_DISABLED ^ WS_DISABLED
title "操作許可中"
stop

#include "llmod3\\llmod3.hsp"
#include "llmod3\\img.hsp"
#include "llmod3\\listview.hsp"
#define ctype RGB(%1,%2,%3) ((%1)|(%2<<8)|(%3<<16))
#const WM_NOTIFY            $0000004E       ; ウィンドウ通知メッセージ  WM_NOTIFY通知メッセージ(コモンコントロールのイベント)
	#const LVN_ITEMCHANGED      $FFFFFF9B   ; アイテム変更通知
	#const NM_CUSTOMDRAW        $FFFFFFF4   ; カスタムドロー通知メッセージ
		#const CDDS_PREPAINT        $00000001   ; 描画サイクルが始まる前
		#const CDDS_ITEMPREPAINT    $00010001   ; アイテムが描画される前
		#const CDRF_NOTIFYITEMDRAW  $00000020   ; コントロールはNM_CUSTOMDRAW通知メッセージをアイテム描画の前後で送ってきます。
		#const CDRF_NEWFONT         $00000002   ; 新しいフォントが指定されました。コントロールは指定された新しいフォントを使用します。
		#const CDRF_DODEFAULT       $00000000   ; コントロールは自分自身で描画します。この描画サイクルではもうNM_CUSTOMDRAW通知メッセージは送られません。
screen 0,500,500,0,3,3 : id_0=ginfo_sel : hwnd_0=hwnd
oncmd gosub *OnNotify, WM_NOTIFY
pos 0,0 : listview 400,200,$61000d-8 : id_listview_0=stat : hwnd_listview_0=objinfo(id_listview_0,2)
listaddcl 0,"No."      ,100 ,0	; listview_0に欄を追加
listaddcl 1,"住所"     ,100,0
listaddcl 2,"電話番号" ,300,0
repeat 50
	listadd cnt,""+cnt,0	; listview_0にアイテムを追加
	listadd cnt,"住所"+cnt,1
	listadd cnt,"電話番号"+cnt,2
loop
index_0=-1
s = "Dummy" : objsize 1,1 : input s : id_obj_Dumy=stat
*mainloop
	wait 1	; <= ここで割り込みを受ける
	if flg_ITEMCHANGED_listview_0 == 1 {
		flg_ITEMCHANGED_listview_0=0
		objsel id_obj_Dumy
		title "選択行INDEX : "+index_0
	}
	goto *mainloop
*OnNotify
	if  ginfo_intid == id_0 {
		dupptr nmhdr,lparam,12		; NMHDR structure
		if nmhdr(0) == hwnd_listview_0 {
			if nmhdr(2) == NM_CUSTOMDRAW {
				; LISTVIEWカスタムドロー通知
				dupptr nmlcd,lparam,56	; NMLVCUSTOMDRAW structure
				if nmlcd(3) = CDDS_PREPAINT {
					return CDRF_NOTIFYITEMDRAW
				}
				if nmlcd(3) = CDDS_ITEMPREPAINT {
					if nmlcd(9) == index_0 {	; アイテムNo.で判定し↓
						nmlcd(12)=RGB(0, $ff, 0)	; アイテムの文字色を変える
						nmlcd(13)=RGB($dd, $dd, $dd)	; アイテムの背景色を変える
					}
					return CDRF_NEWFONT
					;return CDRF_DODEFAULT
				}
			}
			if nmhdr(2) == LVN_ITEMCHANGED {
				; LISTVIEWアイテム変更通知
				flg_ITEMCHANGED_listview_0=1
				dupptr nmlcd,lparam,56	; ? structure
				index_0=nmlcd(3)
				return
			}
		}
	}
	return

既出のリストビューのサンプル

■tooltip

#uselib "hhctrl.ocx"
  #func HtmlHelp          "HtmlHelpA"        sptr,sptr,sptr,sptr
    #const HH_INITIALIZE         $0000001C
    #const HH_UNINITIALIZE          $001D
    #const HH_DISPLAY_TEXT_POPUP $0000000E
#uselib  "user32.dll"
  #func SendMessage       "SendMessageA"     int,int,int,int
    #const WM_CLOSE              $00000010
  #cfunc IsWindowVisible  "IsWindowVisible"  sptr
#define ctype RGB(%1,%2,%3) ((%1)|(%2<<8)|(%3<<16))
onexit *owari
pos 100,100 : syscolor 17 : boxf 100,100,200,200    ; ポップアップを表示する範囲
dim dwCookie,1 : HtmlHelp 0,0,HH_INITIALIZE,varptr(dwCookie)    ; お呪い (HTMLヘルプが呼び出し側と同一のスレッドで実行されるようになる)
*mainloop
    wait 1
    if IsWindowVisible(hwnd_HtmlHelp) {
        if (ginfo_mx < (now_mx-10)) | (ginfo_mx > (now_mx+10)) | (ginfo_my < (now_my-10)) | (ginfo_my > (now_my+10)) {
            SendMessage hwnd_HtmlHelp,WM_CLOSE,0,0    ; これで表示が残った場合、HtmlHelp(HtmlHelpA)は他アプリのウィンドウなので打つ手がない
        }
    }else{
        if mousex >100 &  mousex < 200 &  mousey >100 &  mousey <200 {
            pophelp_str="そこ、そこそこ、そこそこそこ！\nこの表示はHtmlHelp(HtmlHelpA)です"
            pophelp_font="MS UI Gothic,10,,BOLD"
            dim tagHH_POPUP,13 : tagHH_POPUP=13*4,0,0,varptr(pophelp_str),ginfo_mx,ginfo_my,RGB(0,0,$ff),RGB(0,$ff,0),3,3,3,3,varptr(pophelp_font)
            HtmlHelp hwnd,0,HH_DISPLAY_TEXT_POPUP,varptr(tagHH_POPUP) : hwnd_HtmlHelp=stat : now_mx=ginfo_mx : now_my=ginfo_my
            if stat == -1 : dialog "hhctrl.ocxが見つかりませんでした。\nインターネットエクスプローラ(IE)のバージョンが古いかもしれません。",1,"残念！"
        }
    }
    goto *mainloop
*owari
    HtmlHelp 0,0,HH_UNINITIALIZE,varptr(dwCookie)    ; お呪い
    end

API補足説明
#uselib "hhctrl.ocx"
 #func HtmlHelp                   "HtmlHelpA"                   sptr,sptr,sptr,sptr
	;                                                           HWND    hwndCaller,       HTMLヘルプを呼び出すウィンドウのハンドル
	;                                                           LPCSTR  pszFile,          HTMLファイルの名前 (呼び出し側のプログラムと異なるディレクトリに有る場合はパス名も付ける)
	;                                                                                     指定したコマンドがファイル名を必要としない場合も
	;                                                           UINT    uCommand,         コマンドの１つを指定
	;                                                           DWORD   dwData            dwDataは、uCommandの種類により意味が異なる
	#const HH_INITIALIZE            $001C
		; dwDataにはDWORD型変数のポインタを指定(dwCookie)
	#const HH_UNINITIALIZE          $001D
		; dwDataにはHH_INITIALIZEで指定したDWORD型変数のポインタを指定(dwCookie)
	#const HH_DISPLAY_TEXT_POPUP    $000E
		; dwDataにはHH_POPUP構造体（配列のポインタ）を指定
		;  (0) int         cbStruct			4*13
		;  (1) HINSTANCE   hinst			リソースを含むプログラムまたは、dllのインスタンスハンドルを指定 (idStringが0の時またはファイル名を表すときは無視される)
		;  (2) HUINT       idString			0またはリソースIDまたはテキストファイルのトピックID
		;  (3) HLPCTStr    pszText			idStringが０の時表示するテキストを指定
		;  (4) HPOINT      pt				表示するポップアップウィンドウの上辺の中心をどこに持っていくかを指定します。
		;  (5) ↓
		;  (6) HCOLORREF   clrForeground	ポップアップウィンドウのフォアグラウンドカラーのRGB値を指定 (-1でシステムカラー)
		;  (7) HCOLORREF   clrBackground	背景色のRGB値を指定 (-1でシステムカラー)
		;  (8) HRECT       rcMargins		上下・左右のマージン値を指定 (-1でデフォルト)
		;  (9) ↓
		; (10) ↓
		; (11) ↓
		; (12) HLPCTStr    pszFont			フォントを指定します。

●命令/関数

■exist

■ディスクの情報

●ファイル

■ファイルのオープン制御

#include "kernel32.as"	; CloseHandle,CreateFileを使用
	#const GENERIC_WRITE          0x40000000	; 書き込みアクセスです。データの書き込みとファイルポインタの移動ができます。
	#const GENERIC_READ           0x80000000	; 読み取りアクセスです。データの読み取りとファイルポインタの移動ができます。
	#const OPEN_EXISTING          0x00000003	; ファイルをオープンします。指定ファイルが存在していない場合、関数は失敗します。デバイス上 (コンソールも含む) でこの関数を使う場合は、このフラグを指定しなければなりません。
	#const FILE_ATTRIBUTE_NORMAL  0x00000080	; ほかのどの属性も設定されていません。この属性フラグが単独で指定された場合のみ有効です。
onexit goto *owari
screen 0,900,200
trg_dir =dir_desktop
trg_file=trg_dir+"\\新しいテキスト ドキュメント.txt"
exist trg_dir+"\\nul"
if strsize != -1 {
	mes "\""+trg_dir+"\"ﾌｫﾙﾀﾞが存在します"
	chdir trg_dir
	buf_list="" : t_file_name="" : nfile=0
	dirlist buf_list,"*.txt",1
	mes "\""+trg_dir+"\"ﾌｫﾙﾀﾞの.txtﾌｧｲﾙ数 : "+stat
	exist trg_file
	if strsize != -1 {
		mes "\""+trg_file+"\"のｻｲｽﾞ : "+strsize
		CreateFile varptr(trg_file),GENERIC_WRITE|GENERIC_READ,0,0,OPEN_EXISTING,FILE_ATTRIBUTE_NORMAL,0
		if stat != -1 {
			;ﾌｧｲﾙｵｰﾌﾟﾝ成功 => オープンしたママに
			hwnd_file=stat
		}
	}else{
		mes "\""+trg_file+"\"ﾌｧｲﾙは存在しないか、使用できません"
		notesel buf_list
		repeat notemax
			noteget t_file_name,cnt
			if t_file_name != "" {
				exist trg_dir+"\\"+t_file_name
				if strsize != -1 {
					nfile++
				}
			}
		loop
		mes "\""+trg_dir+"\"ﾌｫﾙﾀﾞの開くことのできる.txtﾌｧｲﾙ数 : "+nfile
	}
}else{
	mes "\""+trg_dir+"\"ﾌｫﾙﾀﾞは存在しないか、使用できません"
}
stop
*owari
	;終了時にクローズする
	if hwnd_file != 0 : CloseHandle hwnd_file
	end

●64bit版Windows

■64bit版Windows かどうか

■ファイルシステムリダイレクタ

#include "user32.as"
#define WM_SYSCOMMAND	$00000112
#define SC_MINIMIZE	$0000F020
#define SC_RESTORE	$0000F120
#include  "kernel32.as"
#const PROCESS_TERMINATE   0x0001
onexit *owari
; 64bit版Windows かどうか調べる --------------
newcom oWshShell, "WScript.Shell"
ProgramFiles_86 = oWshShell("ExpandEnvironmentStrings","%ProgramFiles$x86$%")
delcom oWshShell
if ProgramFiles_86 != "" {
	if instr(ProgramFiles_86,0,"%") == -1 {
		flg_64=1
	}
}
; --------------------------------------
if flg_64 {
	exec dir_win+"\\Sysnative\\cmd.exe /C start osk.exe",2
	;↑どういうわけかexec"osk.exe"ではosk.exeの起動に失敗するので
	;  Sysnativeエイリアスを利用してネイティブのシステム ディレクトリ(C:\Windows\System32)の
	;  64bit版cmd.exeを実行し、その64bit版cmd.exeからosk.exeを実行している
}else{
	exec "osk.exe"
}
stop
*owari
	; スクリーンキーボードを終了する -----------
	FindWindow "OSKMainClass", 0
	if stat {
		hkey=stat
		pid=0 : GetWindowThreadProcessId hkey,varptr(pid)
		OpenProcess  PROCESS_TERMINATE, 1, pid
		hProcess=stat
		if hProcess {
			TerminateProcess hProcess, 0
			CloseHandle  hProcess
		}
	}
	; ------------------------------------------
	end